Печать

[tref777 [?]]

Я написал такой скрипт:

Код: AutoIt [Выделить]

#include <IE.au3>
#include <file.au3>
Dim $aRecords
$name = InputBox("Загрузка аудио", "Введите название песни:")
$oIE = _IECreate("vkontakte.ru/audio", 0, 0)
$sHTML = _IEBodyReadHTML($oIE)
FileWrite("temphtml.txt", $sHTML)
_FileReadToArray("temphtml.txt", $aRecords)
For $i = 1 To $aRecords[0]
    $location = StringInStr($aRecords[$i], $name)
    If $location <> 0 Then
        For $i = $i To 1 Step -1
        $SoundLoc1 = StringInStr($aRecords[$i], "http://cs")
        $SoundLoc2 = StringInStr($aRecords[$i], ".mp3")
        $count = $SoundLoc2 - $SoundLoc1
        $string = StringMid($aRecords[$i], $SoundLoc1, $count)
           If $SoundLoc1 <> 0 AND $SoundLoc2 <> 0 Then
               ExitLoop
           EndIf
       Next
       ExitLoop
       EndIf
   Next
        InetGet($string & ".mp3", $name & ".mp3")
    ProcessClose("iexplore.exe")
    FileRecycle("temphtml.txt")

 

Он работает только для первых песен в списке и при условии что выполнен вход в ВК, через IE

[Redline [?]]

Давно делал парсер с выводом форматов (тип кодека видео и разрешение по короткой стороне) для youtube, но они снова сменили код, вот обновленный:

Код: AutoIt [Выделить]

#include <Array.au3>
Dim $aLinksInput[1] = ['http://www.youtube.com/watch?v=p7H7heGDqoY'] ; ссылка должна начинаться на http://www.
Dim $aFormat[12][2] = [['5', 'FLV 240p'], ['17', '3gp'], ['13', '3gp'], ['18', 'MP4 360p'], ['22', 'MP4 720p (HD)'], ['34', 'FLV 360p'], _
['35', 'FLV 480p'], ['37', 'MP4 1080p (HD)'], ['38', 'MP4 Original (HD)'], ['43', 'WebM 480p'], ['44', 'WebM 480p'], ['45', 'WebM 720p (HD)']] ; массив форматов youtube.com
Dim $aSimbols[12][2] = [['\u00', '%'], ['%7C', '|'], ['%26', '&'], ['%3B', ';'], ['%2B', '+'], ['%22', '"'], _
['%3A', ':'], ['%2F', '/'], ['%3F', '?'], ['%3D', '='], ['%2C', ','], ['&amp', '']] ; массив для восстановления символов пунктуации из кодировки
;~  $ProxyServer = 'proxy ip'
;~  $ProxyUser = 'user'
;~  $ProxyPass = 'pass'
For $z = 0 To UBound($aLinksInput) - 1
    $oHTTP = ObjCreate('WinHttp.WinHttpRequest.5.1') ; объект WinHTTP создается каждый раз, иначе выдаются кривые ссылки
;~      $oHTTP.SetProxy(2, $ProxyServer)
    $sUrl = StringReplace($aLinksInput[$z], '.com/v/', '.com/watch?v=') ; приводим ссылку к нужному виду
    $oHTTP.Open('GET', $sUrl, False)
;~      $oHTTP.SetCredentials($ProxyUser, $ProxyPass, 0)
    $oHTTP.Send('')
    $oHTTP.WaitForResponse
    $sHTML = $oHTTP.ResponseText
    $sOut = StringRegExpReplace($sHTML, '(?si).*?"url_encoded_fmt_stream_map": "(.*?)".*$', '$1') ; получаем строку со всеми ссылками на ролик
    $sTitle = BinaryToString(StringToBinary(StringRegExpReplace($sHTML, '(?si).*?<meta name="title" content="(.*?)">.*$', '$1'), 4)) ; получаем названия ролика и переводим в кодировку UTF-8
    $sTitle = StringRegExpReplace($sTitle, '(?si)(&.*?;)', '') ; убираем теги (типа "&quote;")из названия ролика
    $sOut = StringRegExpReplace($sOut, '%(25)+', '%')
    For $i = 0 To UBound($aSimbols) - 1
        $sOut = StringReplace($sOut, $aSimbols[$i][0], $aSimbols[$i][1]) ; восстанавливаем кодировку пунктуации
    Next
    $aLinks = StringRegExp($sOut, '(?si)(http.*?)&quality.*?itag=(\d+)', 3) ; получаем массив из ссылок на ролики и их форматов
    $Format = False
    For $i = 0 To UBound($aLinks) - 1 Step 2
        $aLinks[$i] = $aLinks[$i] & '&title=' & $sTitle ; дописываем к ссылкам тег "title" иначе ролик будет называться "videoplayback"
        For $j = 0 To UBound($aFormat) - 1 ; расшифровка формата
            If $aFormat[$j][0] = $aLinks[$i + 1] Then
                $aLinks[$i + 1] = 'Format: ' & $aFormat[$j][1] & ' [' & $aLinks[$i + 1] & ']'
                $Format = True
                ExitLoop
            EndIf
        Next
        If Not $Format Then $aLinks[$i + 1] = 'Format: unknown [' & $aLinks[$i + 1] & ']'
        ConsoleWrite($aLinks[$i + 1] & @CRLF) ; выдача форматов для ссылки
        ConsoleWrite($aLinks[$i] & @CRLF) ; выдача ссылок в консоль (в _ArrayDisplay() ссылки обрезаются, т.к. слишком длинные)
    Next
    ConsoleWrite('------------------' & @CRLF)
    $oHTTP = 0 ; удаляем объект WinHTTP
Next

[Arei [?]]

мне кажется так будет надежнее, сделать скрытый режим.

Код: AutoIt [Выделить]

#include <IE.au3>
#include <file.au3>
#include <GUIConstantsEx.au3>
#include <WindowsConstants.au3>
Dim $aRecords
$name = InputBox("Загрузка аудио", "Введите название песни:")
$Form1 = GUICreate("Form1", 1, 1, 9999, 9999)
$Obj1 = ObjCreate("Shell.Explorer.2")
$Obj1_ctrl = GUICtrlCreateObj($Obj1, 0, 0, 616, 400)


GUISetState(@SW_HIDE)

$oIE = _IENavigate($Obj1, "vkontakte.ru/audio")


$sHTML = _IEBodyReadHTML($Obj1)
FileWrite("temphtml.txt", $sHTML)
_FileReadToArray("temphtml.txt", $aRecords)
For $i = 1 To $aRecords[0]
    $location = StringInStr($aRecords[$i], $name)
    If $location <> 0 Then
        For $i = $i To 1 Step -1
        $SoundLoc1 = StringInStr($aRecords[$i], "http://cs")
        $SoundLoc2 = StringInStr($aRecords[$i], ".mp3")
        $count = $SoundLoc2 - $SoundLoc1
        $string = StringMid($aRecords[$i], $SoundLoc1, $count)
           If $SoundLoc1 <> 0 AND $SoundLoc2 <> 0 Then
               ExitLoop
           EndIf
       Next
       ExitLoop
       EndIf
   Next
        InetGet($string & ".mp3", $name & ".mp3")
    FileRecycle("temphtml.txt")
 

Добавлено: Ноябрь 14, 2011, 07:48:44

на этапе Код: AutoIt [Выделить]
InetGet("http://vkontakte.ru/audio","1.txt")
 
возникают проблемы с логином. Насколько я понимаю нужно быть залогиненым из IE, иначе он возвращает код странички авторизации...

да это так, но можно ведь легко авторизоваться.

[tref777 [?]]

Код: AutoIt [Выделить]

InetGet("http://vkontakte.ru/audio", "html")
$file = FileRead("html")
If StringInStr($file, "Чтобы просматривать эту страницу, нужно зайти на сайт") Then
    $login = InputBox("логин", "логин")
    $pass = InputBox("пароль", "пароль")
    InetGet("http://vkontakte.ru/login.php?m=1&email="&$login&"&pass="&$pass, "html")
    $file = InetGet("http://vkontakte.ru/audio", "html")
EndIf
FindBlue()
FindBlack()
    FileRecycle("html")



Func FindBlue()
local $metka1 = ';return false;">'
local $metka2 = '</a> </span>'
local $plus = 16
Local $pos1
Local $start = 1
$file = FileRead("html")
$pos1 = 1
$start = 1
While $pos1 <> 0
$pos1 = StringInStr($file, $metka1, 0, 1, $start)
$pos2 = StringInStr($file, $metka2, 0, 1, $pos1)
$start = $pos1 + 1
$startMid = $pos1 + $plus
$count = $pos2 - $startMid
$name = StringMid($file, $startMid, $count)
If $pos1 <> 0 And $pos2 <> 0 Then
    $linkpos1 = StringInStr($file, 'http://cs', 0, -1, $start)
    $linkpos2 = StringInStr($file, '.mp3', 0, -1, $start)
    $linkStartMid = $linkpos1 + 9
    $linkCount = $linkpos2 - $linkStartMid
    $link = StringMid($file, $linkStartMid, $linkCount)
    InetGet("http://cs"&$link&".mp3", $name&".mp3")
    EndIf
WEnd
EndFunc


Func FindBlack()
local $metka1 = 'class="title">'
local $metka2 = '</span><span'
local $plus = 14
Local $pos1
Local $start = 1
$file = FileRead("html")
$pos1 = 1
$start = 1
While $pos1 <> 0
$pos1 = StringInStr($file, $metka1, 0, 1, $start)
$pos2 = StringInStr($file, $metka2, 0, 1, $pos1)
$start = $pos1 + 1
$startMid = $pos1 + $plus
$count = $pos2 - $startMid
$name = StringMid($file, $startMid, $count)
If $pos1 <> 0 And $pos2 <> 0 Then
    $linkpos1 = StringInStr($file, 'http://cs', 0, -1, $start)
    $linkpos2 = StringInStr($file, '.mp3', 0, -1, $start)
    $linkStartMid = $linkpos1 + 9
    $linkCount = $linkpos2 - $linkStartMid
    $link = StringMid($file, $linkStartMid, $linkCount)
    InetGet("http://cs"&$link&".mp3", $name&".mp3")
EndIf
WEnd
EndFunc




 

если кому не лень напишите интерфейс нормальный. Буду благодарен)) 

[Medic84 [?]]

Код: AutoIt [Выделить]

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>
#include <StaticConstants.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>


Global $metka1 = ';return false;">', $metka2 = '</a> </span>', $plus = 16
Global $metka12 = 'class="title">', $metka22 = '</span><span', $plus2 = 14


$MainForm = GUICreate("Скачивание музыки с контакта", 352, 220, 192, 124)
GUICtrlCreateTab(8, 8, 329, 201)
GUICtrlCreateTabItem("Главная")
$ProgressDownload = GUICtrlCreateProgress(16, 152, 313, 17)
$ID_Login = GUICtrlCreateInput("Логин", 16, 65, 145, 21)
GUICtrlSetState(-1, $GUI_DISABLE)
$ID_Pass = GUICtrlCreateInput("Пароль", 176, 65, 153, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_PASSWORD))
GUICtrlSetState(-1, $GUI_DISABLE)
$Download_label = GUICtrlCreateLabel("Статус: ", 16, 104, 313, 41)
GUICtrlCreateLabel("Введите Логин и Пароль: ", 16, 40, 136, 17)
$Cancel_But = GUICtrlCreateButton("Отмена", 112, 176, 121, 25)
GUICtrlSetState(-1, $GUI_DISABLE)
$Login_But = GUICtrlCreateButton("Логин", 226, 37, 100, 20)
GUICtrlSetState(-1, $GUI_DISABLE)
GUISetState(@SW_SHOW)

$String = BinaryToString(InetRead("http://vkontakte.ru/audio"))

If StringInStr($String, "Чтобы просматривать эту страницу, нужно зайти на сайт") Then
    GUICtrlSetState($Login_But, $GUI_ENABLE)
    GUICtrlSetState($ID_Login, $GUI_ENABLE)
    GUICtrlSetState($ID_Pass, $GUI_ENABLE)
    Do
        $nMsg = GUIGetMsg()
    Until $nMsg = $Login_But
    $login = GUICtrlRead($ID_Login)
    $pass = GUICtrlRead($ID_Pass)
    InetRead("http://vkontakte.ru/login.php?m=1&email="&$login&"&pass="&$pass)
    $String = BinaryToString(InetRead("http://vkontakte.ru/audio"))
EndIf

Find($String, $metka1, $metka2, $plus)
Find($String, $metka12, $metka22, $plus2)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit

    EndSwitch
WEnd

Func Find($String, $metka1, $metka2, $plus)
Local $pos1 = 1
Local $start = 1

While $pos1 <> 0
$pos1 = StringInStr($String, $metka1, 0, 1, $start)
$pos2 = StringInStr($String, $metka2, 0, 1, $pos1)
$start = $pos1 + 1
$startMid = $pos1 + $plus
$count = $pos2 - $startMid
$name = StringMid($String, $startMid, $count)
ConsoleWrite($pos1 & $pos2)
If $pos1 <> 0 And $pos2 <> 0 Then
    $linkpos1 = StringInStr($String, 'http://cs', 0, -1, $start)
    $linkpos2 = StringInStr($String, '.mp3', 0, -1, $start)
    $linkStartMid = $linkpos1 + 9
    $linkCount = $linkpos2 - $linkStartMid
    $link = StringMid($String, $linkStartMid, $linkCount)
    $hDownload = InetGet("http://cs"&$link&".mp3", @ScriptDir & "\Music\" &$name&".mp3",1,1)
    GUICtrlSetData($Download_label, "Статус:"&@CRLF&"Загрузка: " & $name&".mp3")
    GUICtrlSetState($Cancel_But, $GUI_ENABLE)
    Do
        $Data = InetGetInfo($hDownload)
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE
                Exit
            Case $Cancel_But
                GUICtrlSetData($ProgressDownload, 0)
                Return
        EndSwitch
        GUICtrlSetData($ProgressDownload, $Data[0]/$Data[1]*100)
        Sleep(200)
    Until InetGetInfo($hDownload, 2)
    InetClose($hDownload)
    EndIf
WEnd
EndFunc

Осталось довести до ума 

[Medic84 [?]]

Довел до ума и переписал функцию. Люблю парсить страницы =)

Используйте на здоровье. Один минус - Скачивает только первые 50 песен.

Код: AutoIt [Выделить]

#include <ButtonConstants.au3>
#include <EditConstants.au3>
#include <GUIConstantsEx.au3>
#include <ProgressConstants.au3>
#include <StaticConstants.au3>
#include <TabConstants.au3>
#include <WindowsConstants.au3>

$MainForm = GUICreate("Скачивание музыки с контакта", 352, 220, 192, 124)
GUICtrlCreateTab(8, 8, 329, 201)
GUICtrlCreateTabItem("Главная")
$ProgressDownload = GUICtrlCreateProgress(16, 152, 313, 17)
$ID_Login = GUICtrlCreateInput("Логин", 16, 65, 145, 21)
GUICtrlSetState(-1, $GUI_DISABLE)
$ID_Pass = GUICtrlCreateInput("Пароль", 176, 65, 153, 21, BitOR($GUI_SS_DEFAULT_INPUT,$ES_PASSWORD))
GUICtrlSetState(-1, $GUI_DISABLE)
$Download_label = GUICtrlCreateLabel("Статус: ", 16, 104, 313, 41)
GUICtrlCreateLabel("Введите Логин и Пароль: ", 16, 40, 136, 17)
$Cancel_But = GUICtrlCreateButton("Старт", 112, 176, 121, 25)
$Login_But = GUICtrlCreateButton("Логин", 226, 37, 100, 20)
GUICtrlSetState(-1, $GUI_DISABLE)
GUISetState(@SW_SHOW)

While 1
    $nMsg = GUIGetMsg()
    Switch $nMsg
        Case $GUI_EVENT_CLOSE
            Exit
        Case $Cancel_But
            LoadMusics()
    EndSwitch
WEnd

Func LoadMusics()
    $String = BinaryToString(InetRead("http://vkontakte.ru/audio"))
    GUICtrlSetData($Cancel_But, "Отмена")
If StringInStr($String, "Чтобы просматривать эту страницу, нужно зайти на сайт") Then
    GUICtrlSetState($Login_But, $GUI_ENABLE)
    GUICtrlSetState($ID_Login, $GUI_ENABLE)
    GUICtrlSetState($ID_Pass, $GUI_ENABLE)
    GUICtrlSetData($Download_label, "Статус:"&@CRLF&"Нет авторизации. Введите Логин и Пароль в форму и нажмите Логин")
    Do
        $nMsg = GUIGetMsg()
    Until $nMsg = $Login_But
    $login = GUICtrlRead($ID_Login)
    $pass = GUICtrlRead($ID_Pass)
    InetRead("http://vkontakte.ru/login.php?m=1&email="&$login&"&pass="&$pass)
    GUICtrlSetState($Login_But, $GUI_DISABLE)
    GUICtrlSetState($ID_Login, $GUI_DISABLE)
    GUICtrlSetState($ID_Pass, $GUI_DISABLE)
    $String = BinaryToString(InetRead("http://vkontakte.ru/audio"))
EndIf
    $URLs = StringRegExp ($String, '(?i)(?U).*value="(.+),.+".+', 3)
    $Names = StringRegExp ($String, '(?i)(?U).*onclick=".+">(.+)</span><span class="user">.*', 3)
For $i = 0 To UBound($Names) - 2
    $Names[$i] = StringRegExpReplace($Names[$i],'(</a>|</b>|<span class="title">|<a href="".+onclick="Audio\.showLyrics.+false;">|&#38;#.+;|">|\:)',"")
    $Names[$i] = StringRegExpReplace($Names[$i],'(\\|/)',"_")
    $Names[$i] = StringStripWS($Names[$i],7)
Next

For $i = 0 To UBound($URLs) - 2
    If Not FileExists(@ScriptDir & "\Music") Then DirCreate(@ScriptDir & "\Music")
    $hDownload = InetGet($URLs[$i], @ScriptDir & "\Music\" &$Names[$i]&".mp3",1,1)
    GUICtrlSetData($Download_label, "Статус:"&@CRLF&"Загрузка: " & $Names[$i])
    GUICtrlSetState($Cancel_But, $GUI_ENABLE)
    Do
        $Data = InetGetInfo($hDownload)
        $nMsg = GUIGetMsg()
        Switch $nMsg
            Case $GUI_EVENT_CLOSE
                Exit
            Case $Cancel_But
                GUICtrlSetData($Download_label, "Статус:"&@CRLF&"Отменено пользователем.")
                GUICtrlSetData($ProgressDownload, 0)
                GUICtrlSetData($Cancel_But, "Старт")
                Return
        EndSwitch
        GUICtrlSetData($ProgressDownload, $Data[0]/$Data[1]*100)
    Until InetGetInfo($hDownload, 2)
    InetClose($hDownload)
Next
GUICtrlSetData($Cancel_But, "Старт")
EndFunc
 

[madmasles [?]]

Medic84,
Посмотрите этот скрипт CreatoR`a.
Я им пользовался, скачивает быстрее и симпатичнее.

[Medic84 [?]]

madmasles  [?]

Я им пользовался, скачивает быстрее и симпатичнее.

Лень переделывать, да и скрипт Creator'a у меня тормозит из за ListViewProgress

[Medic84 [?]]

Ну Вот в общем то - что я напилил за сегодня. 
На Рабочий проект пока не очень тянет, много моментов надо допиливать, но поработать - сойдет =)

VKMD.zip

[komorov74 [?]]

А видео так слабо сделать    Только не убогим Fly а MP4 что бы хотябы ссылки на скачку выдавало!!!!!! Скажу ха это 6 СПАСИБ!!!!!!!!!!!1

[Medic84 [?]]

komorov74
У меня времени нет на это. Я сейчас VK_API пишу, как время будет - покажу как это можно сделать. Тем более на самом VK_API

[Arei [?]]

вы файл удалили.

[Medic84 [?]]

Arei
Я его доделывать начал =) Она теперь базируется на VK API... Поэтому убрал, до выхода UDF

• luhta
• Djus
• Medic84
• areostar
• lorents
• vollod
• Viktor1703
• mysres
• sngr
• yaodnako
• La2Angel
• Александр
• Andrei7
• yaguar666
• C2H5OH
• teges
• beliy
• zuroin
• troyan90
• Колян)
• valdur2000
• Yashied
• madmasles
• VladUs
• Mdsanta
• Kaster
• DarWiM
• Dm666
• chirva
• slepen