Анализ бинарных данных с помощью рег. выражений

[Yashied]

Друзья, нужна помощь "регулярщиков"... Есть некая последовательность байт (данные битмапа):

0x000000000000000000000000000000000000000000000000C4C1C100D4CECE00C0B8B80000000000...

или

0x
00000000
00000000
00000000
00000000
00000000
00000000
C4C1C100
D4CECE00
C0B8B800
00000000
...

Нужно с помощью рег. выражений определить содержит ли этот бмтмап полупрозрачные точки или нет. За это отвечает четвертый байт для каждой точки. Т.е., если хотя бы один четвертый байт из всей последовательности не равен нулю, то возвращаем 1, в противном случае - 0. В данном примере полупрозрачности нет, т.к. одни нули...

Добавлено:

Другими словами, нужен шаблон, который из вешеприведенной строки убирает каждые первые 6 символов из 8 возможных. Тогда я могу записать так:

$sData = '0x000000000000000000000000000000000000000000000000C4C1C100D4CECE00C0B8B80000000000'
$sPattern = ?

If StringReplace(StringRegExpReplace(StringTrimLeft($sData, 2), $sPattern, ''), '0', '') Then
	ConsoleWrite('1' & @CR)
Else
	ConsoleWrite('0' & @CR)
EndIf

 

[SyDr]

Аналогично. Данные изначально в бинарном виде? Тогда ведь даже не надо переводить в строку.

Возвращаемое значение
@error = 0
0 - битмап не содержит полупрозрачных точек
1 - битмап содержит как минимум одну полупрозрачную точку
@error = 1
0 - входные данные не бинарные
@error = 2
0 - число байтов не кратно 4

$sData = '0x000000000000000000000000000000000000000000000000C4C1C100D4CECE00C0B8B80000000000'

MsgBox(4096, Default, F(Binary($sData)))

Func F($bData)
	If Not IsBinary($bData) Then Return SetError(1, 0, 0)
	If Mod(BinaryLen($bData), 4) <> 0 Then Return SetError(2, 0, 0)

	For $iCount = 4 To BinaryLen($bData) Step 4
		If BinaryMid($bData, $iCount, 1) <> 0x00 Then Return 1
	Next

	Return 0
EndFunc

 

[MockeR]

Вот мой вариант:

Local $sRes = 0
$sData = '0x000000000000000000000000000000000000000000000000C4C1C100D4CECE00C0B8B80000000000'
$sCode = StringTrimLeft($sData, 2)
$sStart = 7
Do
	$sMid = StringMid($sCode, $sStart, 2)
	If $sMid <> 0 Then $sRes = 1
	$sStart += 8
Until $sMid = ""
ConsoleWrite($sRes & @CR)

 

[Yashied]

Спасибо, но я просил с помощью рег. выражений (даже тему так назвал). Проверить в массиве я и сам могу, но скорость... Например битмап 128x128 содержит 16384 точек с соответствующими последствиями... Именно поэтому я и хотел использовать рег. выражения. В принципе я уже и сам составил шаблон. Вроде правильно...

$sData = '0x000000000000000000000000000000000000000000000000C4C1C100D4CECE00C0B8B80000000000'

If StringReplace(StringRegExpReplace(StringTrimLeft($sData, 2), '(.{6})(.{2})', '\2'), '0', '') Then
	ConsoleWrite('1' & @CR)
Else
	ConsoleWrite('0' & @CR)
EndIf

 

[SyDr]

Поменял последний 0 на 1, функция всё равно 0 возвращает.

Вот мой вариант:

$sData = '0x000000000000000000000000000000000000000000000000C4C1C100D4CECE00C0B8B80000000000'

MsgBox(4096, Default, F($sData))

Func F($sData)
	If StringRegExp(StringTrimLeft($sData, 2), "\A(.{6}0{2})*\Z") Then Return 0
	Return 1
EndFunc

 

[Yashied]

Поменял последний 0 на 1, функция всё равно 0 возвращает.

;$sData = '0x000000000000000000000000000000000000000000000000C4C1C100D4CECE00C0B8B80000000000'
$sData = '0x000000000000000000000000000000000000000000000000C4C1C100D4CECE00C0B8B80000000001'

If StringReplace(StringRegExpReplace(StringTrimLeft($sData, 2), '(.{6})(.{2})', '\2'), '0', '') Then
    ConsoleWrite('1' & @CR)
Else
    ConsoleWrite('0' & @CR)
EndIf

Все работает.

:-\

 

[CreatoR]

Yashied [?]

В принципе я уже и сам составил шаблон. Вроде правильно

Так вроде правильнее:

$sData = '0x000000000000000000000000000000000000000000000000C4C1C100D4CECE00C0B8B80000000000'

If StringInStr(StringRegExpReplace($sData, '0x|(.{6})(.{2})', '\2'), '1') Then
    ConsoleWrite('1' & @CR)
Else
    ConsoleWrite('0' & @CR)
EndIf

 

[Yashied]

StringInStr() не пойдет, т.к. не обязательно должна быть 1, любое число, отличное от 0.

 

[CreatoR]

Yashied [?]

StringInStr() не пойдет, т.к. не обязательно должна быть 1, любое число, отличное от 0.

Тогда так:

$sData = '0x000000000000000000000000000000000000000000000000C4C1C100D4CECE00C0B8B80000000000'

If Not StringRegExp(StringRegExpReplace($sData, '0x|(.{6})(.{2})', '\2'), '^0+$') Then
    ConsoleWrite('1' & @CR)
Else
    ConsoleWrite('0' & @CR)
EndIf

 

[asdf8]

А если так:

$str = '0x000000000000000000000000000000000000000000000000C4C1C100D4CECE00C0B8B80000000000'
$str = '0x0000000100000001'
$str = StringReplace($str, '0x', '')

$out = StringRegExp($str, '^(.{6}(00))+$')
ConsoleWrite('->' & $out & @CRLF)

 

[Yashied]

Всем спасибо, сделал так:

$sData = '0x000000000000000000000000000000000000000000000000C4C1C100D4CECE00C0B8B80000000000'

If StringReplace(StringRegExpReplace($sData, '0x|(.{6})(.{2})', '\2'), '0', '') Then
	ConsoleWrite('1' & @CR)
Else
	ConsoleWrite('0' & @CR)
EndIf

И вот, для чего мне это все было нужно.

 

[CreatoR]

asdf8 [?]

А если так

Во, тогда и ничего другого не нужно:

$sData = '0x000000000000000000000000000000000000000000000000C4C1C100D4CECE00C0B8B80000000000'

If Not StringRegExp($sData, '^(0x)?(.{6}(00))+$') Then
    ConsoleWrite('1' & @CR)
Else
    ConsoleWrite('0' & @CR)
EndIf

 

[Yashied]

Супер! ~ в 6 раз быстрее моего варианта (хотя время и так незначительное).

 

[Suppir]

Можно еще на 5 - 10% ускорить, если сохраняющие скобки лишние убрать.

$sData = '0x000000000000000000000000000000000000000000000000C4C1C100D4CECE00C0B8B8000000000'

If Not StringRegExp($sData, '^0x(?:.{6}00)+$') Then
    ConsoleWrite('1' & @CR)
Else
    ConsoleWrite('0' & @CR)
EndIf

 

[Yashied]

Да, действительно.