Объект Scripting.Dictionary произвольно создает ключ

[joiner]

Пример

#include <Array.au3>
Local $oDict = ObjCreate('Scripting.Dictionary')
$oDict.CompareMode = 1
Local $vKey = 0
Local $vValue = $oDict.Item($vKey) ; читаем не существующий ключ
Local $Array = $oDict.Keys()
_ArrayDisplay($Array)

Если убрать чтение значения, то ключей нет
Это баг или особенность? не нашел пояснений

 

[Cytrus]

Таким выражением вы добавляете ключ в коллекцию, если он отсутствует.

 

[joiner]

Разве?

Item
Устанавливает или читает новое значение указанного ключа. Значение может быть типом данных: строка, числа целое и с плавающей точкой, логическое значение, бинарные данные.

$oDict.Item($vKey) = $vNewValue ; устанавливает значение или добавляет если не существует
$vValue = $oDict.Item($vKey) ; читает значение

 

[Cytrus]

Ну да.

Так добавляется ключ, если он отсутствует.

#include <Array.au3>
Local $oDict = ObjCreate('Scripting.Dictionary'),$Array,$v
$oDict.Item(333)
$Array = $oDict.Keys()
_ArrayDisplay($Array, "111")
$v=$oDict.Item(444)
$Array = $oDict.Keys()
_ArrayDisplay($Array, "222")
$oDict.Item(555)
$Array = $oDict.Keys()
_ArrayDisplay($Array, "333")
$v=777
$oDict.Key(555) = $v
$Array = $oDict.Keys()
_ArrayDisplay($Array, "444")

 

[joiner]

Cytrus [?]

Так добавляется ключ, если он отсутствует.

это я уже понял, экспериментальным образом. когда ловил плавающий баг в своем коде
нашел в справке майкрософта

Если ключ не найден при изменении элемента, с указанным _newitem_создается новый ключ . Если ключ не найден, при попытке возврата существующего элемента, создается новый ключ и его соответствующего элемента оставить пустым.

Отсюда
в нашей справке
нет этого. просьба к тому, кто имеет доступ, дополнить описание в русской справке

 

[InnI]

joiner [?]

в нашей справке нет этого

И не только в нашей. Некоторые даже считают этот способ экзотическим
4.4. Неявное добавление ключа в Dictionary

 

[CreatoR]

А если так:

#include <Array.au3>

Local $oDict = ObjCreate('Scripting.Dictionary')
$oDict.CompareMode = 1
Local $vKey = 0
Local $vValue = _GetKey($oDict, $vKey) ; читаем не существующий ключ

Local $Array = $oDict.Keys()
_ArrayDisplay($Array)

Func _GetKey($oDict, $sKey)
	Local $fExists = $oDict.Exists($sKey)
	Local $sRet = $oDict.Item($sKey)
	
	If Not $fExists Then
		;ConsoleWrite($oDict.Exists($sKey) & @CRLF)
		$oDict.Remove($sKey)
	EndIf
	
	Return $sRet
EndFunc

или так:

Local $vValue = ($oDict.Exists($vKey) ? $oDict.Item($vKey) : '') ; читаем не существующий ключ