Запуск сприпта (в ехе) с нужными параметрами

[Trans]

Ребят, подскажите как запустить скомпилированный скрипт при этом передав ему 2 строки, а именно логин и пароль, из другого скрипта

 

[firex]

1

Local $sLogin = "user"
Local $sPass = "password"

Run( '2.exe /login="' & $sLogin & '" /password="' & $sPass & '"' )

2

Local $vLogin = StringRegExp( $CmdLineRaw, '/login="([^\"]+)"', 1 )
	If IsArray( $vLogin ) Then $vLogin = $vLogin[0]

Local $vPass = StringRegExp( $CmdLineRaw, '/password="([^\"]+)"', 1 )
	If IsArray( $vPass ) Then $vPass = $vPass[0]

MsgBox( 64, "", "Login=" & $vLogin & @LF & "Pass=" & $vPass )

*Поправил упущенный момент с кавычкой.

 

[Trans]

Вот только в строке пароля выдаёт значение 0 :(

 

[ivsatel]

Trans
Вот такой код поместить в клиента:

Opt('MustDeclareVars', 1)

Local $sStrCmdLine = '', $aArr

If $CmdLine[0] Then
	For $i = 1 To UBound($CmdLine) - 1
		$sStrCmdLine &= $CmdLine[$i]
	Next
	For $i = 1 To UBound($CmdLine) - 1
		RunWithCmdPar(StringRegExpReplace($CmdLine[$i], '[\\/-]', ''))
		If $i == UBound($CmdLine) - 1 Then Exit
	Next
EndIf

Func RunWithCmdPar($a)
	$aArr = StringRegExp($sStrCmdLine, $a, 3)
	If IsArray($aArr) Then
		Switch $aArr[0]
			Case 'A_cr'
				ConsoleWrite('A' & @LF)
			Case 'B'
				ConsoleWrite('B' & @LF)
			Case 'C'
				ConsoleWrite('C' & @LF)
			Case 'D'
				ConsoleWrite('D' & @LF)
			Case 'E'
				ConsoleWrite('E' & @LF)
			Case 'help'
				ConsoleWrite('Show Mes...' & @LF)
				MsgBox(64, 'Help', 'help')
		EndSwitch
	EndIf
EndFunc   ;==>RunWithCmdPar

ConsoleWrite('Continue job...' & @LF)

Соответственно значения менять на свои.
Это обработка переданных параметров. Если параметры переданы, то клиент обработает их и завершит работу. Если параметры не переданы то продолжит работу. Немного изменить регулярное выражение для пароля и логина.
В принципе смысл тот же, что предложил firex.

 

[Trans]

ivsatel вариант firex больше подходит) вот надо решить проблему с паролем)

 

[_dron_]

Run( '2.exe /login="' & $sLogin & '" /password="' & $sPass & '"');<------- & '"'

исправь

зы: в конце не хватает ковычки вот и не работает

 

[ivsatel]

Или так:

Opt('MustDeclareVars', 1)

Local $sStrCmdLine = '', $aArr, $aLogin, $aPassword

If $CmdLine[0] Then
	For $i = 1 To UBound($CmdLine) - 1
		$sStrCmdLine &= $CmdLine[$i] & ' '
	Next
	For $i = 1 To UBound($CmdLine) - 1
		RunWithCmdPar(StringRegExpReplace($CmdLine[$i], '[\\/-]', ''))
		If $i == UBound($CmdLine) - 1 Then
			MsgBox(64, 'Переданные параметры', '$aLogin = '&$aLogin[0]&@LF&'$aPassword = '&$aPassword[0])
			Exit
		EndIf
	Next
EndIf

Func RunWithCmdPar($a)
	$aLogin = StringRegExp($sStrCmdLine, '(?is).*?login=(\S+)\s?', 3)
	$aPassword = StringRegExp($sStrCmdLine, '(?is).*?password=(\S+)\s?', 3)
EndFunc   ;==>RunWithCmdPar

ConsoleWrite('Continue job...' & @LF)

Проверить так:

"C:\Program Files\AutoIt3\AutoIt3.exe" /ErrorStdOut "C:\Documents and Settings\User\Local Settings\Temp\temp.au3" login=user password=123456

 

[Trans]

_dron_, Спасибо)