Как минимальным кодом разбить строку по заданному правилу?

[Tapok]

Строка такого типа:

AAzxdcf125ggbvcoorrrrGGsfsSSS

Надо при нахождении рядом одинаковых символов разбить строку на несколько подстрок. В подстроку входит только один из рядом стоящих одинаковых символов, строчные и заглавные буквы считаются за одинаковые и тоже разделяются.
Для приведенной выше строки будет так:

A
Azxdcf125g
gbvco
or
r
r
rG
Gsfs
S
S
S

Полученные строки можно поместить в массив.

 

[firex]

Мой вариант:
(С учетом регистра). Для его отключения добавьте в начало регулярного выражения (?i)

#Include <Array.au3>

$sText = 'AAzxdcf125ggbvvcoorrrrGGsfsSSSS' ;A Azxdcf125g gbv vco or r r rG GsfsS S S S
$aRet = _Split($sText)
_ArrayDisplay($aRet)

Func _Split($String)
	Local $iPos, $_Pos = 1, $aDlm, _
		$iLen = StringLen($String)

	If Not $iLen Then Return
	; *
	Local $aRet[$iLen + 1] = [1]
	; ---
	While 1
		$iPos = $_Pos
		; -
		$aDlm = StringRegExp($sText, '(.)\1{1}', 2, $iPos)
		If @Error Then
			$aRet[$aRet[0]] = StringTrimLeft($sText, $_Pos - 1)

			ExitLoop
		EndIf

		$_Pos = @Extended - 1
		$aRet[$aRet[0]] = StringMid($sText, $iPos, $_Pos - $iPos)
		$aRet[0] += 1
	WEnd
	ReDim $aRet[$aRet[0] + 1]
	; ---
	Return $aRet
EndFunc

 

[Tapok]

firex, спасибо большое!

 

[InnI]

Такой вариант

$Str = "AAzxdcf125ggbvcoorrrrGGsfsSSS"
$Arr = StringSplit($Str, "")
If UBound($Arr) < 2 Then Exit
$Buf = $Arr[1]
For $i = 1 To $Arr[0] - 1
  If $Arr[$i] = $Arr[$i + 1] Then $Buf &= "|"
  $Buf &= $Arr[$i + 1]
Next
$Arr = StringSplit($Buf, "|", 2)

#include <Array.au3>
_ArrayDisplay($Arr)

 

[Tapok]

InnI, спасибо, все работает! Код все меньше и меньше ;)
Эта идея мне тоже пришла в голову, только реализовать не смог

 

[edyapd]

Мой вариант

#include <Array.au3> ; for _ArrayDisplay
$Str = "AAzxdcf125ggbvcoorrrrGGsfsSSS"
$Str = StringRegExpReplace($Str, '(?i)([A-zА-яЁё])(?=\1)', '\1' & '|')
$Arr = StringSplit($Str, "|", 2)
_ArrayDisplay($Arr)

 

[Tapok]

edyapd, в строке могут быть любые символы, например:

"AAzxdcf125gg++bvcoorrrrG//\\GsfsSSS"

 

[edyapd]

Можете вставить универсальную строку

$Str = StringRegExpReplace($Str, '(?i)(.)(?=\1)', '\1' & '|')

Но желательно давать исходные данные сразу, а не по мере решения задачи.

 

[Tapok]

edyapd, спасибо! Я сам очень люблю регулярки